比较流行的装备增加“暴击”属性的脚本实例

[@main]
#IF
#ACT
OPENMERCHANTBIGDLG 9 14 0 0 1 1 1 395 15
#say
<Img:25:9:0:8>　\
　　　  <暴击大师/SCOLOR=254>\
　      <工作人员:/SCOLOR=70><尊敬的玩家您好!/SCOLOR=251><苍龙传奇感谢一路有您/SCOLOR=242>\
<┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈/SCOLOR=83>\
<1./SCOLOR=70><提供极品+7且幸运+7武器,我可以为你的武器免费打造1点暴击属性/SCOLOR=242>\
<2./SCOLOR=70><提供幸运+3的项链,可使用5万元宝为您的项链打造暴击1～3的属性/SCOLOR=242>\
<3./SCOLOR=70><您也可以使用5000元宝将您的项链暴击属性清洗掉/SCOLOR=242>\
<4./SCOLOR=70><项链打造暴击时,属性为随机1～3点,回收价格也不一样/SCOLOR=250>\
<┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈/SCOLOR=83>\
<> <IMG:192:9:0:-10/@免费武器暴击><>    <IMG:193:9:0:-10/@付费项链暴击><>    <IMG:194:9:0:-10/@清洗项链暴击>\
<┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈/SCOLOR=83>\

[@免费武器暴击]
#IF
#ACT
GetUserItemName 1 10

#IF
Equal S10 屠龙
#ACT
GOTO @检测武器暴击A
break

#IF
Equal S10 嗜魂法杖
#ACT
GOTO @检测武器暴击B
break

#IF
Equal S10 霸者之刃
#ACT
GOTO @检测武器暴击C
break

#IF
Equal S10 苍龙の斩
#ACT
GOTO @检测武器暴击A
break

#IF
Equal S10 苍龙の杖
#ACT
GOTO @检测武器暴击B
break

#IF
Equal S10 苍龙の剑
#ACT
GOTO @检测武器暴击C
break
#ELSEACT
MESSAGEBOX 目前只支持:屠龙、嗜魂、霸者之刃和苍龙级别的武器支持武器附魔暴击.
break

[@检测武器暴击A]
#IF
CHECKNEWITEMVALUE 1 0 > 0
#ACT
MESSAGEBOX 提示：你的武器都已经增加过暴击，不能为你提供服务。
break

#IF
CheckItemAddValue 1 0 > 6
CheckItemAddValue 1 3 > 6
#ACT
SetNewItemValue 1 0 = 1
SENDMSG 7 恭喜你的武器获得1点暴击！
GOTO @MAIN
break
#ELSEACT
MESSAGEBOX 提示：对不起，你的武器不是攻击+7或幸运+7，我不能为你提供服务。
break

[@检测武器暴击B]
#IF
CHECKNEWITEMVALUE 1 0 > 0
#ACT
MESSAGEBOX 提示：你的武器都已经增加过暴击，不能为你提供服务。
break

#IF
CheckItemAddValue 1 1 > 6
CheckItemAddValue 1 3 > 6
#ACT
SetNewItemValue 1 0 = 1
SENDMSG 7 恭喜你的武器获得1点暴击！
GOTO @MAIN
break
#ELSEACT
MESSAGEBOX 提示：对不起，你的武器不是魔法+7或幸运+7，我不能为你提供服务。
break

[@检测武器暴击C]
#IF
CHECKNEWITEMVALUE 1 0 > 0
#ACT
MESSAGEBOX 提示：你的武器都已经增加过暴击，不能为你提供服务。
break

#IF
CheckItemAddValue 1 2 > 6
CheckItemAddValue 1 3 > 6
#ACT
SetNewItemValue 1 0 = 1
SENDMSG 7 恭喜你的武器获得1点暴击！
GOTO @MAIN
break
#ELSEACT
MESSAGEBOX 提示：对不起，你的武器不是道术+7或幸运+7，我不能为你提供服务。
break

[@付费项链暴击]
#IF
CHECKITEMW 幸运三记忆项链 1
#act
goto @付费项链暴击3
#ELSEACT
goto @付费项链暴击1
break

[@付费项链暴击1]
#IF
CHECKITEMW 幸运三灯笼项链 1
#act
goto @付费项链暴击3
#ELSEACT
goto @付费项链暴击2
break

[@付费项链暴击2]
#IF
CHECKITEMW 幸运三虎齿项链 1
#act
goto @付费项链暴击3
#ELSEACT
MESSAGEBOX 提示：你没有佩戴幸运三项链你找我干嘛。
break

[@付费项链暴击3]
;#IF
;CHECKUSEITEM 3
;#ELSEACT
;MESSAGEBOX 提示：你都没有佩戴项链你找我干嘛。
;break

;#IF
;CheckItemAddValue 3 1 > 2
;#ACT
;MESSAGEBOX 提示：对不起，你的项链不是幸运+3，我不能为你提供服务。
;break

#IF
CHECKNEWITEMVALUE 3 0 > 0
#ACT
MESSAGEBOX 提示：你的项链都已经增加过暴击，不能为你提供服务。
break

#IF
CHECKGAMEGOLD > 49999
#ACT
GAMEGOLD - 50000
goto @付费项链暴击_1
#ELSEACT
MESSAGEBOX 提示：你身上都没有50000元宝，我不能为你提供服务。
break

[@付费项链暴击_1]
#IF
RANDOM 20
#ACT
MOV N$幸运点数 3
SetNewItemValue 3 0 = <$STR(N$幸运点数)>
SENDMSG 7 恭喜你的项链获得<$STR(N$幸运点数)>点暴击！
GOTO @MAIN
break
#IF
RANDOM 5
#ACT
MOV N$幸运点数 2
SetNewItemValue 3 0 = <$STR(N$幸运点数)>
SENDMSG 7 恭喜你的项链获得<$STR(N$幸运点数)>点暴击！
GOTO @MAIN
break
#IF
#ACT
MOV N$幸运点数 1
SetNewItemValue 3 0 = <$STR(N$幸运点数)>
SENDMSG 7 恭喜你的项链获得<$STR(N$幸运点数)>点暴击！
GOTO @MAIN
break

[@清洗项链暴击]
#IF
CHECKNEWITEMVALUE 3 0 < 1
#ACT
MESSAGEBOX 提示：你的项链都没有增加过暴击，你洗什么玩意。
break

#IF
CHECKGAMEGOLD > 4999
#ACT
GAMEGOLD - 5000
SetNewItemValue 3 0 = 0
SENDMSG 7 恭喜已经帮你的项链的暴击清洗了！
GOTO @MAIN
#ELSEACT
MESSAGEBOX 提示：你身上都没有5000元宝，我不能为你提供服务。
break